home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Network Support Library
/
RoseWare - Network Support Library.iso
/
btrieve
/
xtr401.exe
/
PATCH401.BAT
< prev
next >
Wrap
DOS Batch File
|
1991-06-20
|
3KB
|
127 lines
echo off
CLS
echo *** MAKE SURE THAT YOU USE THE ORIGINAL (UNPATCHED) RELEASED VERSION
echo OF THE PRODUCT YOU ARE PATCHING. PATCHING AN ALREADY PATCHED COPY
echo MAY CAUSE UNPREDICTABLE ERRORS.
echo
echo WHEN PATCHING THIS PRODUCT, BOTH THE XTRIEVE.EXE AND THE CORRESPONDING
echo XREPORT.OVL FILES WILL BE PATCHED.
echo
IF %1! == ! GOTO PARAM
IF %1 == NET GOTO ENSET
IF %1 == net GOTO ENSET
IF %1 == OS2 GOTO ENSET
IF %1 == os2 GOTO ENSET
IF %1 == SIN GOTO ENSET
IF %1 == sin GOTO ENSET
IF %1 == REXEC GOTO REXEC
IF %1 == rexec GOTO REXEC
GOTO PARAM
::
:ENSET
SET XTR_FIL=XTRIEVE.EXE
SET XTR_OVL=XREPORT.OVL
SET XTRO_FIL=XTR%1.ORG
SET XTRO_OVL=XREP%1.ORG
SET XTRP_FIL=XPAT%1.401
SET XTRP_OVL=RPAT%1.401
IF %1 == OS2 SET XTRP_OVL=SKIP
IF %1 == os2 SET XTRP_OVL=SKIP
GOTO MPATCH
::
:REXEC
SET XTR_FIL=RPTEXEC.EXE
SET XTR_OVL=SKIP
SET XTRO_FIL=RPTEXEC.ORG
SET XTRO_OVL=SKIP
SET XTRP_FIL=RXPAT.401
SET XTRP_OVL=SKIP
GOTO MPATCH
::
:MPATCH
::
:: PATCHING EXECUTABLE FILE
::
IF NOT EXIST PI.EXE GOTO NOPI
IF NOT EXIST %XTRP_FIL% GOTO NOPAT
IF NOT EXIST %XTR_FIL% GOTO NOFILE
IF NOT EXIST %XTRO_FIL% REN %XTR_FIL% %XTRO_FIL%
IF EXIST %XTR_FIL% DEL %XTR_FIL%
:INPATCH
echo
echo %XTR_FIL% VERSION 401 ** PATCHING ..........
echo
COPY %XTRO_FIL% %XTR_FIL%
PI %XTR_FIL% %XTRP_FIL%
::
:: PATCHING REPORT OPTION FILE
::
IF %XTRP_OVL% == SKIP GOTO FIXDONE
IF NOT EXIST %XTRP_OVL% GOTO NOOPAT
IF NOT EXIST %XTR_OVL% GOTO NOOVL
IF NOT EXIST %XTRO_OVL% REN %XTR_OVL% %XTRO_OVL%
IF EXIST %XTR_OVL% DEL %XTR_OVL%
:INOVL
echo
echo %XTR_OVL% REPORT OPTION VERSION 401 ** PATCHING ..........
echo
COPY %XTRO_OVL% %XTR_OVL%
PI %XTR_OVL% %XTRP_OVL%
GOTO FIXDONE
::
:NOPI
echo
echo CANNOT FIND PI.EXE
echo
echo The Novell Patch Install Utility (PI.EXE) is required to install
echo the patches for this product. Please copy PI.EXE to the directory
echo you are working in............................................
GOTO END
::
:NOPAT
echo
echo CANNOT FIND %XTRP_FIL%
GOTO END
::
:NOOPAT
echo
echo CANNOT FIND %XTRP_OVL%
GOTO END
::
:NOFILE
IF EXIST %XTRO_FIL% GOTO INPATCH
echo
echo CANNOT FIND %XTR_FIL%
GOTO END
::
:NOOVL
IF EXIST %XTRO_OVL% GOTO INOVL
echo
echo CANNOT FIND %XTR_OVL%
GOTO END
::
:PARAM
echo THE FORMAT IS:
echo
echo PATCH401 [type]
echo
echo WHERE [type] IS: NET { Xtrieve for NETWORK }
echo OS2 { Xtrieve for OS2 }
echo SIN { Xtrieve SINGLE-USER }
echo REXEC { REPORT EXECUTIVE }
echo
GOTO END
::
:FIXDONE
echo
echo XTRIEVE PRODUCT - %1 VERSION 401 ** PATCH COMPLETE **
echo
::
:END
SET XTR_FIL=
SET XTR_OVL=
SET XTRO_FIL=
SET XTRO_OVL=
SET XTRP_FIL=
SET XTRP_OVL=